10 REM SYSGAIN PROGRAM
20 REM GIVES MAXIMUM ONE-WAY PATH LOSS BETWEEN A TRANSMITTER AND DISTANT
30 REM RECEIVER STATION, FOR SPECIFIED EQUIPMENT CHARACTERISTICS AND A
40 REM REQUIRED SIGNAL TO NOISE RATIO
50 REM VERSION 2.0 OF 14 MAY 1999
60 REM BY ED MUNN, W6OYJ
70 REM
80 REM
90 REM
100 REM
110 REM
120 KEY OFF:CLS
130 PRINT"SYSGAIN PROGRAM"
140 PRINT"FOR A SPECIFIED TRANSMITTER SYSTEM AND DISTANT RECEIVER SYSTEM"
150 PRINT"CALCULATES MAXIMUM PATH ATTENUATION FOR A SPECIFIED S/N RATIO"
160 PRINT
170 INPUT"ENTER TRANSMITTER POWER IN WATTS =";PT
180 INPUT"ENTER TRANSMITTER FEEDLINE LOSS IN DB =";LT
190 INPUT"ENTER TRANSMITTER ANTENNA GAIN IN DB =";GT
200 PRINT
210 INPUT"ENTER RECEIVER ANTENNA GAIN IN DB = ";GR
220 INPUT"ENTER RECEIVER FEEDLINE LOSS IN DB = ";LR
230 INPUT"ENTER RECEIVER NOISE FIGURE IN DB =";NF
240 INPUT"ENTER RECEIVER BANDWIDTH IN KHZ =";BW
250 PRINT
260 INPUT"S/N REQUIRED FOR COMMUNICATIONS IN DB =";SN
270 PRINT
280 REM CALCULATE TRANSMITTER POWER IN DBM
290 PT=PT*1000
300 PT=10*LOG(PT)/LOG(10)
310 REM CALCULATE TRANSMITTER SYSTEM FACTOR
320 TF=PT+GT-LT
330 PRINT"TRANSMITTER STATION SYSTEM FACTOR (DBM) =";TF
340 REM CALCULATE RECEIVER SYSTEM FACTOR
350 SO=-144:REM SENSITIVITY FOR 1KHZ BW RX WITH NF=0 DB, EARTH TEMP
360 BW=10*LOG(BW)/LOG(10):REM BANDWIDTH CORRECTION FACTOR
370 SR=SO+BW+NF:REM RECEIVER SENSITIVITY IN DBM
380 PRINT"RECEIVER SENSITIVITY IN DBM =";SR
390 SF=SR-GR+LR
400 PRINT"RECEIVING STATION SYSTEM FACTOR (DBM) =";SF
410 PRINT
420 PRINT"ONE WAY MAXIMUM PATH ATTENUATION (DB) =";TF-SF-SN
430 PRINT
440 INPUT"TRY ANOTHER CALCULATION (Y/N) ";C$
450 IF C$="Y" GOTO 120
460 IF C$="y" GOTO 120
470 IF C$="N" THEN END
480 IF C$="n" THEN END
490 GOTO 440