10 REM POLPLXCM PROGRAM CALCULATES DIMENSIONS FOR CIRC. WG POLAPLEXERS
20 REM DIMENSIONS REQUESTED, AND ANSWERS ARE IN CENTIMETERS
30 REM VERSION 1.4 OF 30 APR 1999
40 REM BY ED MUNN, W6OYJ
50 REM
60 REM MODIFY NEXT LINE IF PROBE DIAMETER NOT AS STATED
70 PD=1.024:REM ASSUMES PROBE DIAMETER IN MM (#18 AWG WIRE SIZE)
80 REM SEE LINES AT END OF PROGRAM FOR TYPICAL WIRE PROBE SIZES
90 REM
100 KEY OFF:CLS
110 REM
120 REM
130 REM
140 PRINT" POLPLXCM PROGRAM GIVES CM DIMENSIONS FOR CIRCULAR WAVEGUIDE"
150 PRINT" POLAPLEXERS OPERATING IN THE DOMINANT (TE11) MODE"
160 PRINT
170 INPUT" ENTER OPERATING FREQUENCY IN MHZ = ";FO
180 WO=30000/FO:REM OPERATING WAVELENGTH IN CM
190 PRINT" THE OPERATING FREESPACE WAVELENGTH IS ";WO;" CM "
200 PRINT
210 INPUT" ENTER THE INSIDE DIAMETER OF THE CIRCULAR GUIDE IN CM =";DG
220 PRINT
230 C1=1.71*DG:REM C1 IS CUTOFF WAVELENGTH OF DOMINANT TE11 MODE IN CM
240 C2=1.31*DG:REM C2 IS CUTOFF WAVELENGTH OF TM01 MODE IN CM
250 C3=1.03*DG:REM C3 IS CUTOFF WAVELENGTH OF TE21 MODE IN CM
260 PRINT" THE TE11 MODE CUTOFF FREQUENCY IS ";30000/C1;" MHZ "
270 PRINT" THE TM01 MODE CUTOFF FREQUENCY IS ";30000/C2;" MHZ "
280 PRINT" THE TE21 MODE CUTOFF FREQUENCY IS ";30000/C3;" MHZ "
290 WG=WO/SQR(1-((WO/C1)^2)):REM TE11 GUIDE WAVELENGTH IN CM
300 PRINT" THE TE11 MODE GUIDE WAVELENGTH (GW) IS ";WG;" CM "
310 PRINT
320 PRINT" MEASURING FROM THE SHORTED END OF THE GUIDE...."
330 PRINT" THE (L1) SPACING TO THE FIRST PROBE SHOULD BE ";WG/4;" CM "
335 PRINT" THE (L3) SPACING TO THE LO ADJUST SCREW SHOULD BE ";WG/3;" CM "
340 PRINT" THE (L2) SPACING TO THE SECOND PROBE SHOULD BE ";3*WG/4;" CM "
350 PRINT" AND THE OPEN END LENGTH (L4) SHOULD BE ABOUT ";5*WG/4;" CM "
360 PRINT
370 PRINT" QUARTER WAVE PROBE LENGTH (L5) FORMULA GIVES ";WO/4;" CM "
380 WM=WO*10:REM OPERATING WAVELENGTH IN MM
390 PM=PD:REM PROBE DIA IN MM
400 P=PM*3.1416/WM:REM PROBE CIRCUMFERENCE TO WAVELENGTH RATIO
410 L=7494.91*(1+P-SQR(P))/FO:REM K6MBL EMPIRICAL PROBE LENGTH
420 PRINT" K6MBL EMPIRICAL PROBE LENGTH (L5) = ";L;" CM."
430 PRINT
440 END
450 REM WIRE SIZE REFERENCE DATA FOR PROBE CALCULATIONS
460 REM AWG DIA(IN.) DIA(MM.)
470 REM 20 .032 .813
480 REM 18 .0403 1.024
490 REM 16 .0508 1.29
500 REM 14 .0641 1.63