10 REM PATHLOSS PROGRAM COMPUTES ONE-WAY FREE SPACE PATH
20 REM ATTENUATION BETWEEN ISOTROPIC ANTENNAS
30 REM 11 MAY 82*** REVISED 16 MAY 1999
40 REM BY ED MUNN, W6OYJ
50 KEY OFF:CLS
60 PRINT
70 REM
80 PRINT"FREE SPACE ONE-WAY PATH ATTENUATION"
90 PRINT
100 INPUT"ENTER FREQUENCY-MHZ";F
110 PRINT
120 PRINT"CHOICE OF DISTANCE UNITS AS FOLLOWS:"
130 PRINT
140 PRINT"1= STATUTE MILES"
150 PRINT"2= NAUTICAL MILES"
160 PRINT"3= FEET"
170 PRINT"4= KILOMETERS"
180 PRINT
190 INPUT" WHICH ";U
200 PRINT
210 PRINT"ENTER DISTANCE IN UNITS CHOSEN. TO STOP PROGRAM ENTER 0"
220 PRINT
230 ON U GOTO 260,320,380,440
240 PRINT"SYNTAX ERROR-TRY AGAIN"
250 GOTO 110
260 REM DISTANCE IN STATUTE MILES
270 A$="STATUTE MILES"
280 K1=36.584
290 GOSUB 500
300 PRINT
310 GOTO 290
320 REM DISTANCE IN NAUT. MILES
330 A$="NAUT.MILES"
340 K1=37.8
350 GOSUB 500
360 PRINT
370 GOTO 350
380 REM DISTANCE IN FEET
390 A$="FEET"
400 K1=-37.869
410 GOSUB 500
420 PRINT
430 GOTO 410
440 REM DISTANCE IN KILOMETERS
450 A$="KILOMETERS"
460 K1=32.44
470 GOSUB 500
480 PRINT
490 GOTO 470
500 PRINT"***********************":PRINT"DISTANCE: ";A$;"=";
510 INPUT D
520 IF D=0 THEN END
530 A=K1+20*(LOG(D)/LOG(10))+20*(LOG(F)/LOG(10))
540 PRINT"ATTENUATION (DB) = ";A
550 RETURN